forked from organicmaps/organicmaps
Kiryl Kaveryn
173b7e4515
1. add separate `LocalizableTypes.strings` file for the types 2. patch the `GetLocalizedTypeName` cpp function to fetch the value from the proper table Signed-off-by: Kiryl Kaveryn <kirylkaveryn@gmail.com>
47 lines
1.4 KiB
Text
47 lines
1.4 KiB
Text
#include "platform/localization.hpp"
|
|
|
|
#include <algorithm>
|
|
|
|
#import <Foundation/Foundation.h>
|
|
|
|
namespace platform
|
|
{
|
|
std::string GetLocalizedTypeName(std::string const & type)
|
|
{
|
|
auto key = "type." + type;
|
|
std::replace(key.begin(), key.end(), '-', '.');
|
|
std::replace(key.begin(), key.end(), ':', '_');
|
|
|
|
return [NSLocalizedStringFromTableInBundle(@(key.c_str()), @"LocalizableTypes", NSBundle.mainBundle, @"") UTF8String];
|
|
}
|
|
|
|
std::string GetLocalizedBrandName(std::string const & brand)
|
|
{
|
|
auto const key = "brand." + brand;
|
|
return [NSLocalizedStringWithDefaultValue(@(key.c_str()), nil, NSBundle.mainBundle, @(brand.c_str()), @"") UTF8String];
|
|
}
|
|
|
|
std::string GetLocalizedString(std::string const & key)
|
|
{
|
|
return [NSLocalizedString(@(key.c_str()), @"") UTF8String];
|
|
}
|
|
|
|
std::string GetCurrencySymbol(std::string const & currencyCode)
|
|
{
|
|
NSLocale * locale = [NSLocale currentLocale];
|
|
NSString * symbol = [locale displayNameForKey:NSLocaleCurrencySymbol
|
|
value:@(currencyCode.c_str())];
|
|
if (!symbol)
|
|
return currencyCode;
|
|
|
|
return [symbol UTF8String];
|
|
}
|
|
|
|
std::string GetLocalizedMyPositionBookmarkName()
|
|
{
|
|
NSDate * now = [NSDate date];
|
|
return [NSDateFormatter localizedStringFromDate:now
|
|
dateStyle:NSDateFormatterLongStyle
|
|
timeStyle:NSDateFormatterShortStyle].UTF8String;
|
|
}
|
|
} // namespace platform
|