mirror of
https://github.com/KhronosGroup/Vulkan-Headers.git
synced 2025-04-04 20:54:58 +00:00
482af6d865
VULKAN_HEADERS_INSTALL was added since it was believed there was a valid use case for it. After looking into the use case that provoked this change there is no reason to keep VULKAN_HEADERS_INSTALL as an option. Here is the use case we do NOT want to support: https://github.com/KhronosGroup/Vulkan-Headers/pull/416#issuecomment-1622318949 Fundamentally this problem is caused add_subdirectory/find_package not being able to work together flawlessly. Which isn't the responsibility of Vulkan-Headers to fix. It's the responsibility of projects that consume Vulkan-Headers to account for either method. As described by the CMake maintainers: https://discourse.cmake.org/t/idiomatic-way-to-handle-packages-and-add-subdirectory/8400
79 lines
3.3 KiB
CMake
79 lines
3.3 KiB
CMake
# ~~~
|
|
# Copyright (c) 2018-2023 Valve Corporation
|
|
# Copyright (c) 2018-2023 LunarG, Inc.
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
# ~~~
|
|
cmake_minimum_required(VERSION 3.15...3.25)
|
|
|
|
function(vlk_get_header_version)
|
|
set(vulkan_core_header_file "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan/vulkan_core.h")
|
|
if (NOT EXISTS ${vulkan_core_header_file})
|
|
message(FATAL_ERROR "Couldn't find vulkan_core.h!")
|
|
endif()
|
|
|
|
file(READ ${vulkan_core_header_file} ver)
|
|
|
|
if (ver MATCHES "#define[ ]+VK_HEADER_VERSION_COMPLETE[ ]+VK_MAKE_API_VERSION\\([ ]*[0-9]+,[ ]*([0-9]+),[ ]*([0-9]+),[ ]*VK_HEADER_VERSION[ ]*\\)")
|
|
set(MAJOR_VERSION "${CMAKE_MATCH_1}")
|
|
set(MINOR_VERSION "${CMAKE_MATCH_2}")
|
|
else()
|
|
message(FATAL_ERROR "Couldn't get major/minor version")
|
|
endif()
|
|
|
|
if (ver MATCHES "#define[ ]+VK_HEADER_VERSION[ ]+([0-9]+)")
|
|
set(PATCH_VERSION "${CMAKE_MATCH_1}")
|
|
else()
|
|
message(FATAL_ERROR "Couldn't get the patch version")
|
|
endif()
|
|
|
|
set(VK_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}" PARENT_SCOPE)
|
|
endfunction()
|
|
vlk_get_header_version()
|
|
|
|
project(VULKAN_HEADERS LANGUAGES C VERSION ${VK_VERSION_STRING})
|
|
|
|
add_library(Vulkan-Headers INTERFACE)
|
|
add_library(Vulkan::Headers ALIAS Vulkan-Headers)
|
|
target_include_directories(Vulkan-Headers INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
|
|
|
|
if (CMAKE_VERSION VERSION_LESS "3.21")
|
|
# https://cmake.org/cmake/help/latest/variable/PROJECT_IS_TOP_LEVEL.html
|
|
string(COMPARE EQUAL ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} PROJECT_IS_TOP_LEVEL)
|
|
endif()
|
|
|
|
if (PROJECT_IS_TOP_LEVEL)
|
|
option(BUILD_TESTS "Build the tests")
|
|
if (BUILD_TESTS)
|
|
add_subdirectory(tests)
|
|
endif()
|
|
|
|
include(GNUInstallDirs)
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vk_video" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
|
|
install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
|
|
# Preserve source permissions https://github.com/KhronosGroup/Vulkan-Headers/issues/336
|
|
install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/registry" DESTINATION "${CMAKE_INSTALL_DATADIR}/vulkan" USE_SOURCE_PERMISSIONS)
|
|
|
|
set_target_properties(Vulkan-Headers PROPERTIES EXPORT_NAME "Headers")
|
|
|
|
set(cmake_install_dir "${CMAKE_INSTALL_DATADIR}/cmake/VulkanHeaders")
|
|
|
|
install(TARGETS Vulkan-Headers EXPORT VulkanHeadersConfig INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
|
|
install(EXPORT VulkanHeadersConfig NAMESPACE "Vulkan::" DESTINATION "${cmake_install_dir}")
|
|
|
|
set(version_config "${CMAKE_CURRENT_BINARY_DIR}/generated/VulkanHeadersConfigVersion.cmake")
|
|
write_basic_package_version_file("${version_config}" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)
|
|
install(FILES "${version_config}" DESTINATION "${cmake_install_dir}")
|
|
endif()
|